04. Power Enable

✔️Power Enable?

• 전압을 조절해서 줄 수 있는 것
• Lidar-Lite V3: 주황색 선
• Internal Pullup이므로 High일 때 전원 공급

 

✔️Arduino Code

#include <WiFi.h>
#include "time.h"
#include <Wire.h>
#include <LIDARLite.h>



LIDARLite lidarLite, lidarLite2;
int cal_cnt = 0;

const char* ssid = "pia071";
const char* password = "92423071";
const char* ntpServer = "pool.ntp.org";
unsigned long epochTime; 

unsigned long getTime() {
  time_t now;
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    return(0);
  }
  time(&now);
  return now;
}

void initWiFi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.print("Connecting to WiFi ..");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(1000);
  }
  Serial.println(WiFi.localIP());
}

void setup() {
  pinMode(13, OUTPUT);
  digitalWrite(13, LOW);
  pinMode(14, OUTPUT);
  digitalWrite(14, LOW);

  Serial.begin(115200);
  initWiFi();
  configTime(0, 0, ntpServer);

  
  digitalWrite(13, HIGH);
  delay(2000);
  lidarLite.begin(0, true, 0x62); 
  lidarLite.configure(0, 0x62); 
  lidarLite.setI2Caddr(0x64, 0x08, 0x62);
  Serial.println("initial_1");

  digitalWrite(14, HIGH);
  delay(2000);
  lidarLite2.begin(0, true, 0x62); 
  lidarLite2.configure(0, 0x62);
  Serial.println("initial_2");
}

void loop() {
  epochTime = getTime();
  Serial.print("Unix Time: ");
  Serial.println(epochTime);

  int dist;
  int dist2;
  
  if ( cal_cnt == 0 ) {
    dist = lidarLite.distance(true, 0x64);      
    dist2 = lidarLite2.distance(true, 0x62);
  } else {
    dist = lidarLite.distance(false, 0x64); 
    dist2 = lidarLite2.distance(false, 0x62);
  }

  cal_cnt++;
  cal_cnt = cal_cnt % 100;

  Serial.print("dist1:");
  Serial.print(dist);
  Serial.println(" cm");
  Serial.print("dist2:");
  Serial.print(dist2);
  Serial.println(" cm");
  
  
  delay(1000);
}

• GPIO13에 Lidar1 연결
• GPIO14에 Lidar2 연결
• Initial 전에 HIGH로 바꾸어주기
• 전원 공급 후 시간이 조금 필요하므로 delay(2000);